vlookup函數(shù)是一個(gè)非常強(qiáng)大的函數(shù)，在辦公中會(huì)經(jīng)常使用到，根據(jù)使用的情況可以做到不一樣的效果，使用方便。很多用戶不知道怎么使用，下面來看看想想的使用方法吧。

vlookup函數(shù)怎么用：

1、基本用法

參數(shù)介紹

VLOOKUP（找什么，在哪找，找到后返回其右側(cè)對(duì)應(yīng)的第幾列數(shù)據(jù)，精確還是模糊查找）

注意：

需要說明的一點(diǎn)是，Excel中的幫助信息也有錯(cuò)誤，比如在插入函數(shù)功能中VLOOKUP第四參數(shù)的說明就是錯(cuò)的，大家注意不要被誤導(dǎo)哦！如下圖：

2、單條件查找

在E2單元格輸入=VLOOKUP(D2,$A$2:$B$12,2,0)

參數(shù)解釋：

=VLOOKUP(要查找的銷售員,包含銷售員和其銷售額的數(shù)據(jù)源區(qū)域,找到后返回第2列,精確查找)

第一參數(shù)：找什么（或者說按什么查找），按銷售員查找，所以輸入D2

第二參數(shù)：在哪找，數(shù)據(jù)源區(qū)域在A:B列，所以輸入$A$2:$B$12

第三參數(shù)：找到后返回第幾列，我們要查找的是銷售額，銷售額位于B列，即第二參數(shù)中的第二列，所以輸入2

第四參數(shù)：這里要精確查找，所以輸入0

3、借助名稱框查找

選擇A2:B12區(qū)域定義為查找區(qū)域，在E2單元格輸入=VLOOKUP(D2,查找區(qū)域,2,0)

注意：

利用名稱框抓取數(shù)據(jù)區(qū)域，就不用在手工去選擇區(qū)域（名稱框適用于工作簿中所有的工作表）

4、查找返回多列數(shù)據(jù)

要求：

左側(cè)表格是數(shù)據(jù)源區(qū)域，需要在右側(cè)區(qū)域根據(jù)姓名調(diào)取對(duì)應(yīng)的數(shù)據(jù)，黃色區(qū)域是需要填寫公式的區(qū)域

選中H2:K5單元格區(qū)域，輸入以下公式=VLOOKUP($G2,$A$2:$E$9,COLUMN(B1),0)后按Ctrl+Enter組合鍵

5、多條件查找（一對(duì)多查找）

首先在A列增加輔助列，利用COUNT與&組合，在A2輸入=C2&COUNTIF($C$2:C2,C2)

選擇F9:H15單元格輸入=VLOOKUP($F$2&ROW($A1),$A$2:$D$15,COLUMN(B$1),0)，再按Ctrl+Enter

最后為避免出現(xiàn)錯(cuò)誤值，要在外面加上IFERROR函數(shù)，=IFERROR(VLOOKUP($F$2&ROW($A1),$A$2:$D$15,COLUMN(B$1),0),"")

6、從右到左查找（反向查找）

要求：

需要按照給出的編號(hào)查找對(duì)應(yīng)的銷售員姓名，黃色區(qū)域輸入公式

數(shù)據(jù)源格式不允許改動(dòng)時(shí)

在F2單元格輸入=VLOOKUP(E2,IF({1,0},$B$2:$B$12,$A$2:$A$12),2,0)

此處IF函數(shù)，重新構(gòu)建了一個(gè)區(qū)域，將$B$2:$B$12放到第一列，$A$2:$A$12放到第二列，查找并返回對(duì)應(yīng)數(shù)據(jù)

當(dāng)IF的第一參數(shù)是{1,0}時(shí)，相當(dāng)于把條件成立的和不成立的放到一起，構(gòu)建為一個(gè)內(nèi)存數(shù)組，

1代表?xiàng)l件成立的時(shí)候，0代表?xiàng)l件不成立的時(shí)候，{1,0}形成2列，相當(dāng)于B列與A列互換位置

3、區(qū)間查詢

要求：

需要按照等級(jí)劃分規(guī)則，將成績(jī)劃分到其對(duì)應(yīng)的等級(jí)中

建立輔助列

注意：必須是升序排列

此函數(shù)的最后一個(gè)參數(shù)可以隱藏（不輸入），或者輸入1

在C2單元格輸入 =VLOOKUP(B2,$I$2:$J$5,2)，將此公式展開是這樣的： =VLOOKUP(B2,{0,"D";60,"C";80,"B";90,"A"},2)

8、通配符模糊查找

此方法只適用于有唯一一個(gè)符合條件的值，否則用SUMIF比較好

vlookup 的作用：

vlookup 用于查找指定值所對(duì)應(yīng)的另一個(gè)值。例如：查找某件產(chǎn)品的價(jià)格，某個(gè)同學(xué)的某科成績(jī)等。

vlookup 函數(shù)表示：

=vlookup（要查找的值，查找區(qū)域，返回值所在列號(hào)，精確匹配或近似匹配）

參數(shù)說明：

1、要查找的值：可以引用單元格的值，例如 B6;也可以直接輸入，例如“紅色T恤”。

2、查找區(qū)域：用于指定查找范圍，例如 A2:D10。

3、返回值所在列號(hào)：用于指定返回值在哪列，列號(hào)開始必須從指定范圍算起，

例如指定范圍為 B2:E8，則 B 列為第一列，若返回值所在列號(hào)為 3，則從 D 列中返回值。

4、精確匹配或近似匹配：精確匹配用 0 或 False 表示，近似匹配用 1 或 True 表示，

為“可選”項(xiàng)，即可填可不填，若不填，則默認(rèn)值為近似匹配。